Damit Deine Hausautomation auch sauber verstaut werden kann, kannst Du den folgenden Code für OpenSCAD verwenden, um Dir ein Gehäuse selbst auszudrucken. So sind Powerbank, Raspberry Pi mit zwei Busware SCC Funkmodulen und eine mSATA-SSD gut verstaut.

Solltest Du ein Gehäuse mit einer geringeren Höhe benötigen, kannst Du einfach die Variable box_height entsprechend anpassen. Zudem kannst Du auch die Anzahl der Lüftungsöffnungen auf der Rückseite anpassen (Variable a und b in den for-Schleifen). Du kannst Dir natürlich auch direkt die STL-Dateien laden und mit einem Slicer und 3D-Druck-Programm (ich verwende Simplify3D) ausdrucken.

Maße: 9,5 (B) x 17 (L) x 8 (H) cm
Gewicht: ca. 180 g (je nach Infill)
Infill: 7%
Support: none
Brim: skirt

Quellcode für OpenSCAD

/*
Hausautomationsgehäuse
Version 0.1
Author Dr. Dennis Krannich (dennis@krannich.de)
Created at 31.12.2018
Updated at 07.01.2018
*/

// dimensions
rounded_corner      = 5;    // in mm

// dimensions of box
box_width           = 90;   // in mm
box_depth           = 165;  // in mm
box_height          = 70;    // in mm
bottom_thickness    = 1;    // in mm

// dimensions of cover
top_thickness       = 1;    // in mm
top_height          = 5;    // in mm

main_case();
cover_plate();

/*-------------------------------------------------------------------------------------------*/
/*
maincase
*/

module main_case() {
translate([5, 0, 0])
    difference() {
        
        // outer case
        minkowski(){
            cube([box_width-rounded_corner, box_depth-rounded_corner, box_height+bottom_thickness+top_height]);
            cylinder(r=rounded_corner,h=1);
        }
        
        // inner
        translate([-rounded_corner/2, -rounded_corner/2, bottom_thickness])
          cube([box_width, box_depth, box_height+bottom_thickness+top_height]);
        
        // USB-Plug    
        translate([-10, 19, 4+bottom_thickness+top_height+2])
          cube([22, 14, 8]); // 10 x 5 mm + 1 mm margin on each side.

        // Antennas back
        /*
        translate([50, -10, 50])
          rotate([0, 90, 90])
            cylinder(10, 5, 5);  
        
        translate([50, -10, 61])
          rotate([0, 90, 90])
            cylinder(10, 5, 5); 
        */
        
        // Lüftungsschlitze
        for (b = [0:1:2]) {
            for (a = [0:1:19]) {
                translate([-10, 150-(a*7.5), 35+bottom_thickness+top_height+(b*7.5)])
                  rotate([0, 90, 0])
                    cylinder(10, 2, 2);
            }
        }
        
        
        translate([-10, 19, 37])
          cube([22, 14, 8]); // 10 x 5 mm + 1 mm margin on each side.

    }

    // Powerbank Holder
    translate([5, -rounded_corner, bottom_thickness])
      cube([box_width-rounded_corner, 17, 3]);

}
/*-------------------------------------------------------------------------------------------*/
/*
cover plate
*/

module cover_plate() {
translate([-box_width-20, 0, 0])
    union() {
        minkowski(){
            cube([box_width-rounded_corner, box_depth-rounded_corner, top_thickness]);
            cylinder(r=rounded_corner, h=1);
        }
        translate([rounded_corner/2, rounded_corner/2, 0])
            minkowski(){
                cube([box_width-2*rounded_corner, box_depth-2*rounded_corner, top_height]);
                cylinder(r=rounded_corner,h=1);
            }
    }
}
/*-------------------------------------------------------------------------------------------*/